The Games Machine 165/XENIATGM165.ISO/cddata/main.dxr/00008_DirectMedia Xtra Controller Button.ls

Text File | 2003-05-29 | 3.5 KB | 64 lines

property videoSprite, VideoCommand, standardImage, alternateImage, clickedImage, param1, param2

on DoControl me
  case me.VideoCommand of
    #play:
      videoseek(sprite(me.videoSprite), sprite(me.videoSprite).segmentstart)
      videoplay(sprite(me.videoSprite))
    #pause:
      videopause(sprite(me.videoSprite))
    #rewind:
      videoseek(sprite(me.videoSprite), sprite(me.videoSprite).segmentstart)
    #StepForward:
      videopause(sprite(me.videoSprite))
      videoseek(sprite(me.videoSprite), sprite(me.videoSprite).currentTime + 30)
    #StepBackward:
      videopause(sprite(me.videoSprite))
      videoseek(sprite(me.videoSprite), sprite(me.videoSprite).currentTime - 30)
    #Seek:
      videoseek(sprite(me.videoSprite), me.param1)
    #playsegment:
      videoplaysegment(sprite(me.videoSprite), me.param1, me.param2)
  end case
end

on mouseUp me
  set the member of sprite the spriteNum of me to me.standardImage
  DoControl(me)
end

on mouseDown me
  set the member of sprite the spriteNum of me to me.clickedImage
end

on mouseEnter me
  set the member of sprite the spriteNum of me to me.alternateImage
end

on mouseLeave me
  set the member of sprite the spriteNum of me to me.standardImage
end

on beginSprite me
  me.standardImage = the member of sprite me.spriteNum
end

on getPropertyDescriptionList
  if the currentSpriteNum = 0 then
    memdefault = 0
  else
    memref = the member of sprite the currentSpriteNum
    castLibNum = memref.castLibNum
    mb = member(memref).memberNum + 1
    mb2 = member(memref).memberNum + 2
    memdefault = member(mb, castLibNum)
    memdefault2 = member(mb2, castLibNum)
  end if
  p_list = [#VideoCommand: [#comment: "Action:", #format: #symbol, #range: [#play, #pause, #rewind, #StepBackward, #StepForward, #Seek, #playsegment], #default: #play], #param1: [#comment: "First Parameter (Use with seek or playsegment):", #format: #long, #default: 0], #param2: [#comment: "Second Parameter (Use with playsegment):", #format: #long, #default: 0], #videoSprite: [#comment: "DirectMedia Sprite Channel:", #format: #integer, #default: 1], #alternateImage: [#comment: "Rollover Button Cast Member:", #format: #graphic, #default: memdefault], #clickedImage: [#comment: "Clicked Button Cast Member:", #format: #graphic, #default: memdefault2]]
  return p_list
end

on getBehaviorDescription
  return "Used to create Play, Pause, StepForward, StepBackward, Rewind, Seek and PlaySegment control buttons for a DirectMedia Xtra video sprite. You can also attach rollover and alternate images for the clicked buttons" & RETURN & "PARAMETERS:" & RETURN & "Action - Choose the action to perform on mouseUP ( Play, Pause, Rewind, StepBackward, StepForward, Seek, PlaySegment )." & RETURN & "First Parameter: if the Action is Seek than this parameter contains the seek to time (in milliseconds). For the PlaySegment action this parameter contains the starting time of the segment to play (in milliseconds)" & RETURN & "Second Parameter: Used with the PlaySegment action. Contains the ending time of the segment to play (in milliseconds)" & RETURN & "DirectMedia Sprite Channel - Enter the number of sprite channel of the DirectMedia Xtra video that is being controlled." & RETURN & "Rollover Button: the castmember that will be used as the rollover image of the button. Default is the castmember located just after the button castmember" & RETURN & "Clicked Button: the castmember that will be used as the clicked image of the button. Default is the castmember located just after the rollover castmember"
end